' Modification du dossier de stockage des papiers peints OE
' pour une utilisation avec XP SP2


' Ce script modifie l'endroit du registre où OE va chercher le chemin par défaut de ses papiers à lettres 
' et modifie le dit chemin afin de supprimer l'accent du répertoire "Papier à lettres". En effet, cette 
' lettre accentuée crée un bug empechant l'affichage des images contenues dans ces papiers.

' Le script modifie aussi parallèlement le dossier du disque dur où se trouvent ses papiers.
' Après avoir exécuté ce script, redémarrez Outlook Express : les papiers à lettres devraient pouvoir être accessibles comme avant.
' Au sujet des pbs d'images, consultez aussi l'article suivant : http://www.faqoe.com/index.php?bas=/rep/bl.htm

' http://WWW.faqoe.com
'
' P.Gastaldi
' Remerciements à S.Cochran.


Dim objShell, objFso 
Dim strChemPap,strChemFond,objFd
dim strNouveauDossier

if msgbox ("Ce script va modifier le chemin du dossier des papiers à lettres, êtes-vous sur de vouloir continuer ?", vbOKCancel ,"Demande de confirmation") = vbOK then

	' Nom du nouveau dossier par défaut
	strNouveauDossier = "Papier"

	Set objShell = CreateObject("WScript.Shell")
	set objFSO = CreateObject("Scripting.FileSystemObject")
	
	' Dossier des papiers peints et fonds (ce sont les mêmes dossiers)
	strChemPap = objShell.RegRead("HKLM\SOFTWARE\Microsoft\Shared Tools\Stationery\Stationery Folder")
	if strChemPap <> "C:\Program Files\Fichiers communs\Microsoft Shared\Papier" then
		objShell.RegWrite "HKLM\SOFTWARE\Microsoft\Shared Tools\Stationery\Stationery Folder Sauvegarde", strChemPap , "REG_EXPAND_SZ"
		strChemPap = objShell.RegRead("HKLM\SOFTWARE\Microsoft\Shared Tools\Stationery\Backgrounds Folder")
		objShell.RegWrite "HKLM\SOFTWARE\Microsoft\Shared Tools\Stationery\Backgrounds Folder Sauvegarde", strChemPap , "REG_EXPAND_SZ"
	
		strChemPap = objShell.ExpandEnvironmentStrings(strChemPap)
		
		If objFso.FolderExists(strChemPap) Then
			Set objFd = objFso.GetFolder(strChemPap)
				If not objFso.FolderExists(strNouveauDossier) Then
					objFd.Name = strNouveauDossier
				end if
				strChemPap = objFd.Path
				objShell.RegDelete "HKLM\SOFTWARE\Microsoft\Shared Tools\Stationery\Stationery Folder"
				objShell.RegWrite "HKLM\SOFTWARE\Microsoft\Shared Tools\Stationery\Stationery Folder", strChemPap , "REG_SZ"
				'
				objShell.RegDelete "HKLM\SOFTWARE\Microsoft\Shared Tools\Stationery\Backgrounds Folder"
				objShell.RegWrite "HKLM\SOFTWARE\Microsoft\Shared Tools\Stationery\Backgrounds Folder", strChemPap , "REG_SZ"
			set objFd = Nothing
		end if
		if err.number=0 then msgbox "Tout c'est bien déroulé. Le message de stockage des papiers à lettres est désormais " & strChemPap
	else
		msgbox "Votre dossier semble déjà avoir été modifié"
	end if
		
	set objFSO = Nothing
	Set objShell=Nothing
	
	
end if